Internet Explorer（IE）を起動する

Public Class IEWrapper

  Private Shared ReadOnly log As log4net.ILog = log4net.LogManager.GetLogger( _
                System.Reflection.MethodBase.GetCurrentMethod().DeclaringType)

  'IEのwaitのタイムアウト時間 15秒
  Private Shared ReadOnly MAX_WAIT_TIME As New TimeSpan(0, 0, 15)

  Private _ie As SHDocVw.InternetExplorer
  Protected Property IE As SHDocVw.InternetExplorer
    Get
      Return _ie
    End Get
    Set(ByVal value As SHDocVw.InternetExplorer)
      _ie = value
    End Set
  End Property

  Sub New()
  End Sub

  ' 新規IE作成
  Sub NewIE(ByVal url As String)
    IE = New SHDocVw.InternetExplorer()

    ' 初期ページを開く
    Dim isSuccess As Boolean = TryGotoUrl(url, New TimeSpan(0, 1, 0))
    log.WarnFormat("初期ページオープン。{0}", isSuccess)
    IE.Visible = True
  End Sub

  ' URL移動 戻り値はタイムアウトせず成功したか。
  Function TryGotoUrl(ByVal url As String, Optional ByVal timeout As TimeSpan = Nothing) As Boolean
    Try
      GotoUrl(url, timeout)
      Return True
    Catch ex As TimeoutException
      log.Warn(String.Format("GotoUrlに失敗しました。Url={0}", url), ex)
    End Try
    Return False
  End Function

  ' URL移動
  Sub GotoUrl(ByVal url As String, Optional ByVal timeout As TimeSpan = Nothing)
    IE.Navigate(url)
    WaitIE(timeout)
  End Sub

  ' IEがビジー状態の間待つ。戻り値はタイムアウトせず成功したか。
  Protected Function TryWaitIE(Optional ByVal timeout As TimeSpan = Nothing) As Boolean
    Try
      WaitIE(timeout)
      Return True
    Catch ex As TimeoutException
      log.Warn("WaitIEでタイムアウトしました。", ex)
    End Try
    Return False
  End Function

  ' IEがビジー状態の間待つ。タイムアウトしたらTimeoutException例外発生。
  Protected Sub WaitIE(Optional ByVal timeout As TimeSpan = Nothing)
    If timeout.TotalMilliseconds <= 0 Then
      timeout = MAX_WAIT_TIME
    End If
    Dim startTime As DateTime = DateTime.Now
    Do While IE.Busy = True OrElse IE.ReadyState <> SHDocVw.tagREADYSTATE.READYSTATE_COMPLETE
      System.Windows.Forms.Application.DoEvents()
      If DateTime.Now - startTime > timeout Then
        Throw New TimeoutException("WaitIEでタイムアウトしました。")
      End If
    Loop

    System.Threading.Thread.Sleep(100)
  End Sub
End Class

Dim ie As New IEWrapper()
ie.NewIE("http://www.google.co.jp/")